日立 MB-6892 レベル3 VRAMｴﾘｱが移動できるか確認してみる^^

Last Updated on 2020年3月26日 by kabekin

レベル3でCP/MやFLEX9を動作させるためにはALLRAMモードで動作させる必要があると思うのですが、そうなると$400から始まるVRAMエリアは邪魔になりそうです。

というわけで、CRTCの参考書籍を確認してみるとHD46505ではレジスタR12とR13でVRAMの先頭アドレスを指定するとの説明がありました。

早速、L3エミュでCRTCのR12,R13レジスタに何が書かれているのか調べたところ、
R12=$04
R13=$00
と、VRAMの先頭アドレスががそのままセットされておりました^^
レベル3の回路図見た感じではVRAMは独立したメモリがあるわけではなく主記憶の一部を間借りしているだけっぽいので、そのままR12,R13を変更するとVRAMエリアを移動できそうです。

S1の取説にはCRTCの設定パラメータの記述があるのですがレベル3の取説は持っていないのでパラメータが不明(レベル3マーク5の取説をお持ちの方是非貸して下さい^^;;;)

資料が無いのでL3エミュでCRTCのアドレス$FFC6,$FFC7のストア部分をトレースして値を確認。

  ■I/Oアドレス
  $FFC6 CRTC アドレスレジスタ(W)
  $FFC7 CRTC データレジスタ(R/W)
  CRTCにデータをストアする部分 $FB7B
  ■CRTC(HD46505SP)レジスタパラメータ(L3)
 ┌─────────┬─────────────┬─────────────┐
 │水平文字数        │           40文字　       │　         80文字         │
 │NEWON             │     NEWON3       NEWON11 │    NEWON7       NEWON15  │
 │                  │     HIRESO       NORMAL  │    HIRESO       NORMAL   │
 │解像度            │     320*200      80*100  │    640*200      160*100  │
 │SCREEN,,1/,,0     │ﾉﾝｲﾝﾀ ｲﾝﾀﾚｰｽ  ﾉﾝｲﾝﾀ ｲﾝﾀﾚｰｽ│ﾉﾝｲﾝﾀ ｲﾝﾀﾚｰｽ  ﾉﾝｲﾝﾀ ｲﾝﾀﾚｰｽ│
 │MODE-SEL FFD0     │ $00   $00     $40   $40  │ $80    $80    $C0   $C0  │
 │MODE              │        0                 │         1                │
 ├─────────┼─────────────┼─────────────┤
 │R0  水平総文字数  │       $3F           $3F  │        $7F         $7F   │
 │R1  水平表示文字数│       $28           $28  │        $50         $50   │
 │R2  水平同期位置  │       $31           $31  │        $5F         $5F   │
 │R3  同期ﾊﾟﾙｽ幅    │       $85           $85  │        $8A         $8A   │
 │R4  垂直総文字数  │       $1F           $1F  │        $1F         $1F   │
 │R5  ﾄｰﾀﾙﾗｽﾀｱｼﾞｬｽﾄ │       $06           $06  │        $06         $06   │
 │R6  垂直表示文字数│       $19           $19  │        $19         $19   │
 │R7  垂直同期位置  │       $1C           $1C  │        $1C         $1C   │
 │R8  ｲﾝﾀﾚｰｽ&ｽｷｭｰ   │ $40   $43     $40   $43  │ $40    $43    $40  $43   │
 │R9  最大ﾗｽﾀｱﾄﾞﾚｽ  │ $07   $0E     $07   $0E  │ $07    $0E    $07  $0E   │
 │R10 ｶｰｿﾙｽﾀｰﾄﾗｽﾀ   │ $27   $2A     $27   $2E  │ $27    $2E    $27  $2E   │
 │R11 ｶｰｿﾙｴﾝﾄﾞﾗｽﾀ   │ $07   $0F     $07   $0F  │ $07    $0F    $07  $0F   │
 │R12 ｽﾀｰﾄｱﾄﾞﾚｽ(H)  │ $04   $04     $04   $04  │ $04    $04    $04  $04   │
 │R13 ｽﾀｰﾄｱﾄﾞﾚｽ(L)  │ $00   $00     $00   $00  │ $00    $00    $00  $00   │
 │R14 ｶｰｿﾙ(H)       │ $04   $04     $00   $04  │ $04    $05    $04  $04   │
 │R15 ｶｰｿﾙ(L)       │ $00   $00     $00   $00  │ $00    $18    $00  $00   │
 │R16 ﾗｲﾄﾍﾟﾝ(H)     │       N/A           N/A  │        N/A         N/A   │
 │R17 ﾗｲﾄﾍﾟﾝ(L)     │       N/A           N/A  │        N/A         N/A   │
 └─────────┴─────────────┴─────────────┘
  上記のﾉﾝｲﾝﾀﾚｰｽはｲﾝﾀﾚｰｽ→ﾉﾝｲﾝﾀﾚｰｽに変更したときの値
　ﾉﾝｲﾝﾀﾚｰｽからｲﾝﾀﾚｰｽに変更したときもR8～R15までのみストアしていた
　　→R0～R7は同様なのでINIT時のみストア？
　WIDTH80⇔WIDTH40の変更ではR0～R3とR12～R15がストアされた

結局、S1の取説にあったパラメータと同じでした・・・^^;;;

これを踏まえて整理すると、

R4～R7は全モード共通
グラフィック解像度はMODE-SELの違いのみでCRTCパラメータの違いはない
R10,R11,R14,R15はカーソル表示用←設定パラメータではない？
R12,R13はVRAMの先頭アドレス
となるので、
こんな感じにテーブルにまとめてみました。

* CRTCパラメータテーブル(L3)
TBL40   FCB $00,$3F,$28,$31,$85,$FF          ;40文字モード
TBL80   FCB $00,$7F,$50,$5F,$8A,$FF          ;80文字モード
TBLCOM1 FCB $04,$1F,$06,$19,$1C,$FF          ;共通パラメータ1(R4～R9)
TBLCOM2 FCB $0A,$2E,$0F,$04,$00,$04,$00,$FF  ;共通パラメータ2(R10～R15)
TBLIL   FCB $08,$43,$0E,$FF                  ;インタレースモード
TBLNIL  FCB $08,$40,$07,$FF                  ;ノンインタレースモード

各テーブル1バイト目にCRTSのRegNo, その後データ, デリミタを$FFにしてみました。
これをまとめてVRAMが移動できるか確認するテストプログラムを作成^^

FFD0              MODESEL    EQU      $FFD0       ;画面/ACIAモード
FFC6              CRTCAR     EQU      $FFC6       ;CRTCアドレスレジスタ
FFC7              CRTCDR     EQU      $FFC7       ;CRTCデータレジスタ
5000                         ORG      $5000
5000 2000                    BRA      START
5002              START      EQU      *
5002 108EFFC6                LDY      #CRTCAR     ;CRTCアドレスセット
                  * MODE-SELセット
5006 86C0                    LDA      #$C0
5008 B7FFD0                  STA      MODESEL
                  *CRTCセット
500B 308D002E                LEAX     TBL80,PCR
500F 8D13                    BSR      PARAMSET
5011 308D002E                LEAX     TBLCOM1,PCR
5015 8D0D                    BSR      PARAMSET
5017 308D0036                LEAX     TBLIL,PCR
501B 8D07                    BSR      PARAMSET
501D 308D0028                LEAX     TBLCOM2,PCR
5021 8D01                    BSR      PARAMSET
5023 39                      RTS
                  *CRTCにパラメータをセットSub.
                  *X=PARAMテーブルのポインタ
                  *Y=CRTCのアドレスL
5024              PARAMSET   EQU      *
5024 3436                    PSHS     D,X,Y
5026 A680                    LDA      ,X+         ;CRTC RegNo取得
5028 E680         LP1        LDB      ,X+         ;CRTS PARAMを取得
502A C1FF                    CMPB     #$FF
502C 2707                    BEQ      FIN
502E A7A4                    STA      ,Y
5030 4C                      INCA
5031 E721                    STB      1,Y
5033 20F3                    BRA      LP1
5035 35B6         FIN        PULS     D,X,Y,PC
                  * CRTCパラメータテーブル(L3)
5037 003F283185FF TBL40      FCB      $00,$3F,$28,$31,$85,$FF ;40文字モー
503D 007F505F8AFF TBL80      FCB      $00,$7F,$50,$5F,$8A,$FF ;80文字モー
5043 041F06191CFF TBLCOM1    FCB      $04,$1F,$06,$19,$1C,$FF ;共通パラメ
5049 0A2E0F040004 TBLCOM2    FCB      $0A,$2E,$0F,$04,$00,$04,$00,$FF ;共
     00FF
5051 08430EFF     TBLIL      FCB      $08,$43,$0E,$FF ;インタレースモード
5055 084007FF     TBLNIL     FCB      $08,$40,$07,$FF ;ノンインタレースモ

エミュで確認した値とS1の取説にあった値は同じでしたので、
その値をCRTCにセットするだけのプログラムですが、
思うように動作しません・・・・

参考にした書籍によると画面モードによってCRTCに供給されるクロックを変える必要があるそうです。
レベル3の資料でこれを調べると$FFD0にMODE-SELというレジスタがあり40/80文字モードとグラフィックの解像度を変更できるレジスタがありましたのでCRTCのパラメータに加えMODE-SELもセットしています。

S1には上記に加えSCRN-MODEというレジスタがあるようですがL3にはなさそうです。
何か別の手続きが必要で、それが抜けているんだと思います^^;;;

そもそも、CRTCのパラメータを変えただけではダメで他に何かする必要があるのかも・・・

知識がなく、完全に手探り状態です^^;;;

しかし、この状態でも表示は出ているのでVRAMが移動できるものなのか調べてみました。
CRTCの設定でVRAMの先頭アドレスを$3000～と指定して、

$3000～データをセットしてみると、

無事表示されました。

カラーRAMの関係もあるのか文字色は青でした。

カラーRAMの扱い方は調べないとわからないので、簡単に変更できる背景色を変更。
POKE &HFFD0,&HC4

色々と残件が残りましたが、VRAMエリアが移動できることが確認できました。
そんなレベル3VRAM移動の記録・・・

残件メモ
CRTCパラメータ設定後の表示の乱れ
$400～VRAMを移動したときのカラーRAMの扱い